home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d12 / v10n22.arc / LTOA.ASM < prev    next >
Assembly Source File  |  1991-12-08  |  3KB  |  97 lines
  1.         title   LTOA --- Convert long (32-bit) integer to ASCII string
  2.         page    55,132
  3.  
  4. ; LTOA.ASM --- Convert long (32-bit) integer to ASCII string
  5. ;
  6. ; Copyright (C) 1989 Ray Duncan
  7. ;
  8. ; Call with:    DX:AX = 32-bit integer
  9. ;               DS:SI = buffer to receive string,
  10. ;                       must be at least 11 bytes long
  11. ;               CX    = radix
  12. ;
  13. ; Returns:      DS:SI = address of converted string
  14. ;               AX    = length of string
  15. ;
  16. ; Destroys:     BX, DX
  17. ; 
  18. ; Since test for value = zero is made after a digit
  19. ; has been stored, the resulting string will always
  20. ; contain at least one significant digit.
  21.  
  22. _TEXT   segment word public 'CODE'
  23.  
  24.         assume  cs:_TEXT
  25.  
  26.         public  ltoa            
  27. ltoa    proc    near
  28.  
  29.         add     si,11                   ; advance to end of buffer
  30.         push    si                      ; and save that address.
  31.         or      dx,dx                   ; test sign of 32 bit value,
  32.         pushf                           ; and save sign on stack.
  33.         jns     ltoa1                   ; jump if value was positive.
  34.         not     dx                      ; it was negative, take 2's 
  35.         not     ax                      ; complement of the value. 
  36.         add     ax,1
  37.         adc     dx,0
  38.  
  39. ltoa1:  call    divide                  ; divide value by radix
  40.         add     bl,'0'                  ; convert remainder to ASCII digit
  41.         cmp     bl,'9'                  ; in case converting to hex ASCII,
  42.         jle     ltoa2                   ; jump if in range 0-9,
  43.         add     bl,'A'-'9'-1            ; correct digit if in range A-F.
  44.  
  45. ltoa2:  dec     si                      ; back up through buffer
  46.         mov     [si],bl                 ; store this character into string.
  47.         mov     bx,ax                   ; is value = zero yet?
  48.         or      bx,dx
  49.         jnz     ltoa1                   ; no, convert another digit.
  50.  
  51.         popf                            ; was original value negative?
  52.         jns     ltoa3                   ; no, jump
  53.         dec     si                      ; yes, store - sign into output
  54.         mov     byte ptr [si],'-'
  55.  
  56. ltoa3:  pop     ax                      ; calculate length of string
  57.         sub     ax,si
  58.         ret                             ; back to caller.
  59.  
  60. ltoa    endp
  61.  
  62. ;
  63. ; General purpose 32 bit by 16 bit unsigned divide.  This routine must 
  64. ; be used instead of the machine's usual unsigned divide for cases 
  65. ; where the quotient may overflow 16 bits (for example, 100,000 / 2 ).  
  66. ; If called with a zero divisor, this routine returns the dividend 
  67. ; unchanged and gives no warning.
  68. ;
  69. ; Call with:    DX:AX = 32 bit dividend
  70. ;               CX    = divisor
  71. ;
  72. ; Returns:      DX:AX = quotient
  73. ;               BX    = remainder
  74. ;               CX    = divisor (unchanged)
  75. ;
  76. ; Destroys:     Nothing
  77. ;
  78. divide  proc    near            
  79.  
  80.         jcxz    div1                    ; exit if divide by zero
  81.         push    ax                      ; 0:dividend_hi/divisor
  82.         mov     ax,dx
  83.         xor     dx,dx
  84.         div     cx
  85.         mov     bx,ax                   ; BX = quotient1
  86.         pop     ax                      ; remainder1:dividend_lo/divisor
  87.         div     cx
  88.         xchg    bx,dx                   ; DX:AX = quotient1:quotient2
  89.  
  90. div1:   ret                             ; BX = remainder2
  91.  
  92. divide  endp
  93.  
  94. _TEXT   ends
  95.  
  96.         end
  97.